mode属性でテンプレートの使い分け

・通常は1つの要素には1つのテンプレートしか適用できない。mode属性でテンプレートを区分けすれば、同じ要素に複数のテンプレートを使い分けることができる。
・<xsl:template>のmode属性に、重複しない任意の名前を付ける。テンプレート呼び出しの<xsl:apply-templates>で、使いたいmode属性の名前を指定すればよい。

[サンプルXML文書を表示](下のフレームに)

XMLソース

<?xml version="1.0" encoding="Shift_JIS" ?>
<?xml-stylesheet type="text/xsl" href="temp09.xsl"?>
<root>
 <title>2003年11月05日の東証株式第一部情報</title>
 <info><name>銘柄</name><end>終値(円)</end><total>出来高(千株)</total></info>
 <data>
  <kabu><name code="6752">松下</name><end>1529</end><total>12302</total></kabu>
  <kabu><name code="6753">シャープ</name><end>1786</end><total>3964</total></kabu>
  <kabu><name code="6758">ソニー</name><end>4030</end><total>8220</total></kabu>
  <kabu><name code="6764">三洋</name><end>516</end><total>7551</total></kabu>
  <kabu><name code="6501">日立</name><end>692</end><total>21896</total></kabu>
  <kabu><name code="6502">東芝</name><end>440</end><total>17832</total></kabu>
  <kabu><name code="6701">NEC</name><end>1027</end><total>19229</total></kabu>
  <kabu><name code="6702">富士通</name><end>708</end><total>16634</total></kabu> </data>
 <end>以上です(2004/6/7)</end>
</root>

XSLソース

<?xml version="1.0" encoding="Shift_Jis"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="html" encoding="Shift_JIS"/>
 
 <xsl:template match="/">
  <center><H3><xsl:value-of select="root/title"/></H3></center>
  <xsl:apply-templates select="root/data" mode="code"/>
  <xsl:apply-templates select="root/data" mode="end"/>
  <xsl:apply-templates select="root/data"/>
 </xsl:template>
  
 <xsl:template match="data"><!--名前で並べ替え-->
   <xsl:for-each select="kabu/name">
     <xsl:sort select="." data-type="text" order="descending"/>
     <span style="color:magenta"><xsl:value-of select="."/></span><br/>
   </xsl:for-each>
 </xsl:template>
 <xsl:template match="data" mode="code"><!--コード番号で並べ替え-->
   <xsl:for-each select="kabu">
     <xsl:sort select="name/@code" data-type="number" order="ascending"/>
     <span style="color:blue"><xsl:value-of select="name"/>
            (コード：<xsl:value-of select="name/@code"/>)</span><br/>
   </xsl:for-each>
 </xsl:template>
 <xsl:template match="data" mode="end"><!--終値で並べ替え-->
   <xsl:for-each select="kabu">
     <xsl:sort select="end" data-type="number" order="descending"/>
     <span style="color:green"><xsl:value-of select="name"/>
            (終値：<xsl:value-of select="end"/>)</span><br/>
   </xsl:for-each>
 </xsl:template>
</xsl:stylesheet>

end(04/6/7)